Variable: VAR_IN_OUT Permalink

Una variable ‎VAR_IN_OUT‎ es una variable de entrada/salida que forma parte de una interfaz POU y sirve como parámetro formal de paso por referencia.

Sintaxis

<keyword> <POU name>
VAR_IN_OUT
    <variable name> : <data type>;
END_VAR

<keyword> : FUNCTION | FUNCTION_BLOCK | METHOD | PRG

Puede declarar una variable de entrada/salida en la sección de declaración ‎VAR_IN_OUT‎ en los POUs ‎PRG‎, ‎FUNCTION_BLOCK‎, ‎METHOD‎ o ‎FUNCTION‎. La variable ‎VAR_IN_OUT‎ se puede leer y escribir.

Utilización

  • Llame a: Cuando se llama a una POU, la variable formal ‎VAR_IN_OUT‎ recibe la variable real ("pass-by-reference variable") como argumento. En tiempo de ejecución, no se generan copias cuando se pasan parámetros. En su lugar, la variable formal recibe una referencia a la variable real pasada remotamente. Las variables referenciales contienen internamente una dirección de memoria como valor al valor real (pass as pointer, call-by reference). No es posible especificar una constante (literal) o una variable de bits directamente como argumento.

  • Acceso de lectura/escritura dentro del POU: Si la variable se escribe dentro del POU, entonces esto afecta a la variable pasada. Cuando se sale de la POU, los cambios realizados se conservan. Esto significa que un POU utiliza sus variables de ‎VAR_IN_OUT‎ igual que el POU llamante utiliza sus variables. El acceso de lectura siempre está permitido.

  • Acceso de lectura/escritura a distancia: ‎VAR_IN_OUT‎ las variables no pueden leerse ni escribirse directamente a distancia a través de ‎<function block instance name>.<variable name>‎. Esto sólo funciona para las variables ‎VAR_INPUT‎ y ‎VAR_OUTPUT‎.

  • Paso de variables de cadena: Si se pasa una variable de cadena como argumento, la variable real y la variable formal deben tener la misma longitud. De lo contrario, la cadena pasada puede ser manipulada involuntariamente. Este problema no se produce en el caso de los parámetros ‎VAR_OUTPUT CONSTANT‎.

  • Paso de variables de bits: Una variable bit no puede pasarse directamente a una variable ‎VAR_IN_OUT‎ porque necesita una variable intermedia.

  • Transmisión de propiedades: No autorizado

Si se pasa una cadena como variable o constante a una variable formal de ‎VAR_IN_OUT CONSTANT‎, automáticamente se pasa la cadena completa. No es necesario comprobar la longitud de la cadena.

Para más información, consulte: "VAR_IN_OUT CONSTANT" Variable de transferencia

Ejemplo

Pasar matrices

TYPE DUT_A :
STRUCT
        xA: BOOL;
        iB: INT;
END_STRUCT
END_TYPE

FUNCTION_BLOCK FB_SetArray
VAR_IN_OUT
        aData_A : ARRAY[0..1] OF DUT_A; // Formal variable
END_VAR
aData_A[0].xA := TRUE;
aData_A[0].iB := 100;

PROGRAM PLC_PRG
VAR
        fbSetA : FB_SetArray;
        aSpecialData : ARRAY[0..1] OF DUT_A; // Actual variable
END_VAR
fbSetA(aData_A := aSpecialData);
_cds_varinouts_array.png

Pasar cadenas

{attribute 'qualified_only'}
VAR_GLOBAL
        g_sDEV_STATUS : STRING(25) := 'Device_A';
END_VAR

FUNCTION_BLOCK FB_SetStatus
VAR_IN_OUT
        sDeviceStatus : STRING(25); // Formal parameter
END_VAR
sDeviceStatus := CONCAT(sDeviceStatus, ' Activ');

PROGRAM PLC_PRG
VAR
        fbDoB : FB_SetStatus;
END_VAR
fbDoB(sDeviceStatus := GVL.g_sDEV_STATUS); //Call with actual parameter

La variable ‎sDeviceStatus‎ forma parte de la interfaz POU de ‎FB_B‎. Al llamar a ‎fbDoB‎, primero se asigna un nombre de dispositivo a la cadena y luego se manipula la cadena.

_cds_varinouts_string.png

Pasar variables de bits

VAR_GLOBAL
        xBit0 AT %MX0.1 : BOOL;
        xTemp : BOOL;
END_VAR

FUNCTION_BLOCK FB_DoSomething
VAR_INPUT
        xIn : BOOL;
END_VAR
VAR_IN_OUT
        xInOut : BOOL;
END_VAR
IF xIn THEN
        xInOut := TRUE;
END_IF

PROGRAM PLC_PRG
VAR
        xIn : BOOL;
        DoSomething_1  : FB_DoSomething;
        DoSomething_2  : FB_DoSomething;
END_VAR

// The following line of code causes a compiler error:
// C0201: Typ 'BIT' is not equal to type 'BOOL' of VAR_IN_OUT 'xInOut'
DoSomething_1(xIn := xIn, xInOut := xBit0);

// Workaround
xTemp := xBit0;
DoSomething_2(xIn := xIn, xInOut := xTemp);
xBit0 := xTemp;

El programa llama a las instancias del bloque de funciones ‎DoSomething_1‎ y ‎DoSomething_2‎. Como resultado de la asignación directa de la variable de bit ‎xBit0‎ a la entrada ‎VAR_IN_OUT‎, se genera un error de compilador cuando se llama a la instancia ‎DoSomething_1‎. Por el contrario, llamar a la instancia ‎DoSomething_2‎ con la asignación de una variable intermedia es código correcto.